LuckyBlockThorn_Task:
    type: task
    definitions: loc
    script:
    - define looping:++
    - if <[looping]> > 3:
        - stop
    - if !<[loc].exists>:
        - define loc <context.location||<player.location>>
    - define mat <context.material.name||AIR>
    - random:
        - narrate "Hmm... Nothing happened... Perhaps you should try breaking it harder?"
        - teleport <player.location.add[0,200,0]>
        - determine <list[<server.material_types.exclude[<material[air]>].random.name>[display=<util.random.duuid.after[_]>]]> passively
        - cast <server.potion_effect_types.random> d:<util.random.int[5].to[15]> p:<util.random.int[0].to[2]>
        - burn <player> duration:<util.random.int[5].to[15]>s
        - announce <&6><&l><&k><util.random.duuid.after[_]>
        - adjust <player> show_demo
        - strike <player.location>
        - playsound <player.location> sound:<server.sound_types.random> volume:0.5 pitch:<util.random.decimal[0.5].to[2.0]>
        - time <player.world.time.add[12000]>t global <player.world>
        - rotate <player> duration:<util.random.int[5].to[15]>s
        - adjust <player> skin:<server.online_players.random.name>
        - repeat <util.random.int[5].to[15]>:
            - repeat <util.random.int[2].to[4]>:
                - shoot arrow spread:10.0 speed:3.0 origin:<player> shooter:<player>
            - wait 5t
        - heal <util.random.int[5].to[15]>
        - feed amount:<util.random.int[5].to[15]>
        - inventory open d:<server.online_players.random.inventory>
        - repeat <util.random.int[50].to[100]>:
            - adjust <player> item_slot:<util.random.int[1].to[9]>
            - wait 2t
        - repeat <util.random.int[3].to[5]>:
            - repeat 10:
                - adjust <player> fov_multiplier:<[value].div[10]>
                - wait 4t
            - adjust <player> fov_multiplier:-0.00000001
            - wait 10t
            - adjust <player> fov_multiplier:0
        - repeat <util.random.int[5].to[15]>:
            - define ppl <server.online_players>
            - adjust <[ppl]> velocity:<util.random.int[-1].to[1]>,3,<util.random.int[-1].to[1]>
            - foreach <[ppl]>:
                - playeffect <[value].location> effect:lava quantity:15 data:1 offset:0.1
                - playsound sound:ENTITY_GENERIC_EXPLODE <[value].location> volume:0.2
            - wait 2t
        - modifyblock <[loc].add[2,0,2].to_cuboid[<[loc].add[-2,0,-2]>]> fire
        - repeat <util.random.int[5].to[15]>:
            - repeat 20:
                - playeffect effect:LARGE_SMOKE at:<[loc]> quantity:50 offset:0.5 visibility:500
                - wait 2t
            - spawn creeper <[loc]>
        - spawn skeleton <[loc].face[<player.location>]>
        - foreach <list[cow|sheep|chicken|pig]>:
            - spawn <[value]> <[loc].add[<util.random.int[-1].to[1]>,0,<util.random.int[-1].to[1]>].face[<player.location>]>
        - modifyblock <[loc]> <list[bedrock|ender_chest|bookshelf|sponge|slime_block|diamond_block|emerald_block].random>
        - foreach <list[boots|chestplate|leggings|helmet]>:
            - drop <list[diamond|leather|iron|golden|netherite].random>_<[value]> <[loc].add[<util.random.int[-1].to[1]>,1,<util.random.int[-1].to[1]>]>
        - repeat <util.random.int[4].to[8]>:
            - fakespawn <list[creeper|warden|zombie|blaze|ghast|ENDERMAN|SKELETON].random> <player.location.forward_flat[2].face[<player.location>]> duration:15t
            - wait 2s
        - repeat <util.random.int[3].to[6]>:
            - spawn bee <[loc].face[<player.location>]> save:ent target:<player>
        # Fake KillAura LuL
        - repeat 30:
            - if !<player.is_online>:
                - stop
            - foreach <player.location.find_players_within[5].exclude[<player>]> as:target:
                - look <player> <[target].location.above[1.5]>
                - animate <player> animation:ARM_SWING
                - playsound sound:ENTITY_PLAYER_ATTACK_WEAK volume:0.5 <player.location>
                - wait 2t
            - wait 2t
        - repeat <util.random.int[20].to[40]>:
            - drop xp quantity:1 <[loc].center>
            - wait 4t
        - repeat <util.random.int[20].to[40]>:
            - define loc <player.location.add[0,2,0]>
            - define targets <[loc].find_players_within[6].exclude[<player>]>
            - if !<[targets].is_empty>:
                - playeffect <[loc]> effect:portal data:1 visibility:500 quantity:50
                - foreach <[targets]> as:target:
                    - adjust <[target]> velocity:<[loc].face[<[target].location>].direction.vector>
            - wait 5t
        - repeat <util.random.int[3].to[6]>:
            - adjust <player> velocity:0,1.5,0
            - playeffect effect:cloud at:<player.location> quantity:25 offset:0.5 visibility:500
            - wait <util.random.int[3].to[5]>s
        - repeat <util.random.int[20].to[40]>:
            - playeffect SPELL_MOB <player.location> data:1 visibility:300 quantity:50 offset:0.2
            - wait 4t
        - repeat <util.random.int[30].to[50]>:
            - if <[value].mod[5]> == 0:
                - playsound <[loc]> sound:ENTITY_MINECART_INSIDE_UNDERWATER pitch:2
            - define targets <[loc].find_players_within[10]>
            - if <[targets].is_empty>:
                - stop
            - playeffect <[loc]> effect:cloud data:1 visibility:500 quantity:50
            - foreach <[targets]> as:target:
                - define pre_loc <[target].location.face[<[loc]>]>
                - adjust <[target]> velocity:<[pre_loc].with_yaw[<[pre_loc].yaw.add[75]>].with_pitch[-15].direction.vector>
            - wait 2t
        - determine <list[Lucky_Blocks_Item_Meme_Book]> passively
        - repeat <util.random.int[2].to[4]>:
            - inject LuckyBlockThorn_Task
        - spawn wolf[owner=<player>] <[loc]>
        - modifyblock <[mat]> <[loc]>
        - determine NOTHING passively
        - repeat <util.random.int[20].to[40]>:
            - define x <util.random.decimal[-5].to[5]>
            - define z <util.random.decimal[-5].to[5]>
            - define base <[loc].add[<[x]>,0,<[z]>]>
            - playsound sound:ITEM_PICKUP <[base]>
            - playeffect <[base]> effect:FIREWORKS_SPARK visibility:500 quantity:5 data:0 offset:0.1
            - random:
                - drop IRON_INGOT <[base]>
                - drop IRON_INGOT <[base]>
                - drop IRON_INGOT <[base]>
                - drop GOLDEN_APPLE <[base]>
                - drop GOLD_INGOT <[base]>
            - wait 2t
        - repeat <util.random.int[5].to[10]>:
            - spawn zombie <[loc].face[<player.location>]>
        # These below could probably be considered to be put in a task script
        - repeat 1:
            - modifyblock <[loc]> jukebox
            - random:
                - define disc MUSIC_DISC_11
                - define disc MUSIC_DISC_13
                - define disc MUSIC_DISC_5
                - define disc MUSIC_DISC_BLOCKS
                - define disc MUSIC_DISC_CAT
                - define disc MUSIC_DISC_CHIRP
                - define disc MUSIC_DISC_FAR
                - define disc MUSIC_DISC_MALL
                - define disc MUSIC_DISC_MELLOHI
                - define disc MUSIC_DISC_OTHERSIDE
                - define disc MUSIC_DISC_PIGSTEP
                - define disc MUSIC_DISC_STAL
                - define disc MUSIC_DISC_STRAD
                - define disc MUSIC_DISC_WAIT
                - define disc MUSIC_DISC_WARD
            - adjust <[loc]> jukebox_record:<[disc]>
            - adjust <[loc]> jukebox_play:true
            - repeat <util.random.int[3].to[6]>:
                - spawn parrot <[loc].add[<util.random.int[-1].to[1]>,1,<util.random.int[-1].to[1]>].face[<player.location>]>
            - spawn parrot <[loc].above.face[<player.location>]>
        - repeat 1:
            - playsound <player.location> sound:block_glass_break pitch:0.5
            - define player_pos <player.location>
            - modifyblock <[player_pos]> ice no_physics
            - showfake ice <[player_pos].above> players:<server.online_players.exclude[<player>]> d:8s
            - adjust <player> freeze_duration:20s
            - repeat 160:
                - teleport <player> <[player_pos]>
                - wait 1t
            - adjust <player> freeze_duration:0
            - modifyblock <[player_pos]> air no_physics
        - repeat 1:
            - playeffect effect:VILLAGER_HAPPY at:<player.location> visibility:500 quantity:150 offset:0.5
            - playsound sound:ENTITY_WITHER_HURT volume:1 pitch:0.5 <player>
            - cast speed duration:5s amplifier:1 <player>
            - cast INCREASE_DAMAGE duration:5s amplifier:10 <player>
        - repeat 1:
            - wait <util.random.int[10].to[25]>s
            - inject LuckyBlockThorn_Task
        - repeat 1:
            - repeat <util.random.int[10].to[20]>:
                - playeffect <[loc]> effect:lava quantity:1 data:1 offset:0
                - wait 2t
            - modifyblock <[loc]> AIR
            - playeffect <[loc].below> effect:HUGE_EXPLOSION visibility:500 quantity:10 offset:2.0
            - playsound sound:ENTITY_GENERIC_EXPLODE <[loc]> volume:32
            - hurt 20 <[loc].find_players_within[3]>
            - hurt 14 <[loc].find_players_within[5]>
            - hurt 6 <[loc].find_players_within[10]>
            - hurt 1 <[loc].find_players_within[15]>
        - repeat 1:
            - define ppl <server.online_players.random[9999]||<list[]>>
            - if <[ppl].size> > 1:
                - define last_target <[ppl].first>
                - define last_loc <[last_target].location>
                - repeat <[ppl].size.sub[1]>:
                    - define target <[ppl].get[<[value]>]>
                    - define to_target <[ppl].get[<[value].add[1]>]>
                    - teleport <[target]> <[to_target].location>
                    - playsound <[to_target].location> sound:entity_enderman_teleport volume:2 pitch:1
                - teleport <[ppl].last> <[last_loc]>
                - playsound <[last_loc]> sound:entity_enderman_teleport volume:2 pitch:1

Lucky_Blocks_Item_Meme_Book:
    type: book
    title: Book Of Memes
    author: MigMig
    signed: true
    text:
    - maurice